// Last updated 06/06/05
// For use with the latest 3D MovieClip standard navigation code
// The below events code should be pasted in the Zoom slider button 

onClipEvent(load)
{
	// these variables can be customised
	side = "_y"; // should be either "_x" if it's a horizontal slider bar or "_y" if it's a vertical slider bar
	minXY = (-42); // minimum x or y position of the slider bar depending if it is a vertical or horizontal slider bar
	maxXY = (4); // maximum x or y position of the slider bar depending if it is a vertical or horizontal slider bar
	_root.renderWindow.zoom_slider_path = _root.blaze_controls.zoomSlider; // pointer variable to slider bar button withing the render code.
	_root.renderWindow.zoom_slider = true; // enables slider bar within the render code.

	// these variables are not customised
	clickOn = 0;
	range = maxXY - minXY;
	bZoomChanged = false;
	current_z_distance = _root.renderWindow.ZOOM_MINDIST;
}
 
onClipEvent(mouseDown)
{
	if (this.hitTest(_root._xmouse, _root._ymouse, false)==true){
		clickOn = 1;       
	}
}
 
onClipEvent(mouseUp)
{
	clickOn = 0;
}
 
onClipEvent(enterFrame)
{
	if (bZoomChanged){
		maxZoom = _root.renderWindow.ZOOM_MAXDIST;
		minZoom = _root.renderWindow.ZOOM_MINDIST;
		this[side] = minXY + (current_z_distance - minZoom)*range/(maxZoom - minZoom);
		if (this[side] < minXY){ this[side] = minXY; }
		else if (this[side] > maxXY){ this[side] = maxXY; }
		bZoomChanged = false;
	}
	if (clickOn == 1){
		if (side == "_y"){
			myXY =  _parent._ymouse;
		} 
		else{
			myXY =  _parent._xmouse;
		}
		this[side] = myXY;
		if (this[side] < minXY){ this[side] = minXY; }
		else if (this[side] > maxXY){ this[side] = maxXY; }
		
		maxZoom = _root.renderWindow.ZOOM_MAXDIST;
		minZoom = _root.renderWindow.ZOOM_MINDIST;
		_zoom = minZoom + (maxZoom - minZoom)*(this[side] - minXY)/range;
		
		_root.renderWindow.movementState = _root.renderWindow.PANELDRAG_STATE;
		_root.renderWindow.panelButton = _root.renderWindow.ZOOM_PANELBUTTON;
	}
}